linux的arch/arm/mm/proc-(arch).S
mov pc, lr
ENTRY(cpu_v6_proc_fin)
stmfd sp!, {lr}
cpsid if @ disable interrupts
bl v6_flush_kern_cache_all
mrc p15, 0, r0, c1, c0, 0 @ ctrl register
bic r0, r0, #0x1000 @ …i…………
bic r0, r0, #0x0006 @ ………….ca.
mcr p15, 0, r0, c1, c0, 0 @ disable caches
ldmfd sp!, {pc}
/*
* cpu_v6_reset(loc)
*
* Perform a soft reset of the system. Put the CPU into the
* same state as it would be if it had been reset, and branch
* to what would be the reset vector.
*
* – loc – location to jump to for soft reset
*
* It is assumed that:
*/
.align 5
ENTRY(cpu_v6_reset)
mov pc, r0
/*
* cpu_v6_do_idle()
*
* Idle the processor (eg, wait for interrupt).
*
* IRQs are already disabled.
*/
ENTRY(cpu_v6_do_idle)
mcr p15, 0, r1, c7, c0, 4 @ wait for interrupt
mov pc, lr
ENTRY(cpu_v6_dcache_clean_area)
#ifndef TLB_CAN_READ_FROM_L1_CACHE
1: mcr p15, 0, r0, c7, c10, 1 @ clean D entry
add r0, r0, #D_CACHE_LINE_SIZE
subs r1, r1, #D_CACHE_LINE_SIZE
bhi 1b
#endif
mov pc, lr
/*
* cpu_arm926_switch_mm(pgd_phys, tsk)
*
* Set the translation table base pointer to be pgd_phys
*
* – pgd_phys – physical address of new TTB
*
* It is assumed that:
* – we are not using split page tables
*/
ENTRY(cpu_v6_switch_mm)
#ifdef CONFIG_MMU
mov r2, #0
ldr r1, [r1, #MM_CONTEXT_ID] @ get mm->context.id
orr r0, r0, #TTB_FLAGS
mcr p15, 0, r2, c7, c5, 6 @ flush BTAC/BTB
mcr p15, 0, r2, c7, c10, 4 @ drain write buffer
mcr p15, 0, r0, c2, c0, 0 @ set TTB 0
mcr p15, 0, r1, c13, c0, 1 @ set context ID
#endif
mov pc, lr
/*
* cpu_v6_set_pte_ext(ptep, pte, ext)
*
* Set a level 2 translation table entry.
*
* – ptep – pointer to level 2 translation table entry
* (hardware version is stored at -1024 bytes)
* – pte – PTE value to store
* – ext – value for extended PTE bits
*/
armv6_mt_table cpu_v6
ENTRY(cpu_v6_set_pte_ext)
#ifdef CONFIG_MMU
armv6_set_pte_ext cpu_v6
#endif
mov pc, lr
cpu_v6_name:
.asciz “ARMv6-compatible processor”
.align
.section “.text.init”, #alloc, #execinstr
/*
* __v6_setup
*
* Initialise TLB, Caches, and MMU state ready to switch the MMU
* on. Return in r0 the new CP15 C1 control register setting.
*
* We automatically detect if we have a Harvard cache, and use the
* Harvard cache control instructions insead of the unified cache
* control instructions.
*
* This should be able to cover all ARMv6 cores.
*
* It is assumed that:
* – cache type register is implemented
*/
__v6_setup: /*初始化v6处理器，TLB/CACHE，切换到MMU on*/
#ifdef CONFIG_SMP
mrc p15, 0, r0, c1, c0, 1 @ Enable SMP/nAMP mode
orr r0, r0, #0x20
mcr p15, 0, r0, c1, c0, 1
#endif
mov r0, #0
mcr p15, 0, r0, c7, c14, 0 @ clean+invalidate D cache /*清楚cache、buffer*/
mcr p15, 0, r0, c7, c5, 0 @ invalidate I cache
mcr p15, 0, r0, c7, c15, 0 @ clean+invalidate cache
mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
#ifdef CONFIG_MMU
mcr p15, 0, r0, c8, c7, 0 @ invalidate I + D TLBs /*使能TLB*/
mcr p15, 0, r0, c2, c0, 2 @ TTB control register
orr r4, r4, #TTB_FLAGS
mcr p15, 0, r4, c2, c0, 1 @ load TTB1
#endif /* CONFIG_MMU */
adr r5, v6_crval /*设置处理方法v6_crval，看下面*/
ldmia r5, {r5, r6}
mrc p15, 0, r0, c1, c0, 0 @ read control register
bic r0, r0, r5 @ clear bits them
orr r0, r0, r6 @ set them
mov pc, lr @ return to head.S:__ret /*从head.S的 adr lr, __enable_mmu 知道，此时lr为__enable_mmu，即跳转到__enable_mmu处执行。*/
/*
* V X F I D LR
* …. …E PUI. .T.T 4RVI ZFRS BLDP WCAM
* rrrr rrrx xxx0 0101 xxxx xxxx x111 xxxx < forced
* 0 110 0011 1.00 .111 1101 < we want
*/
.type v6_crval, #object /*在上面__v6_setup设置好供以后用。*/
v6_crval:
crval clear=0x01e0fb7f, mmuset=0x00c0387d, ucset=0x00c0187c
.type v6_processor_functions, #object
ENTRY(v6_processor_functions)
.word v6_early_abort
.word pabort_noifar
.word cpu_v6_proc_init
.word cpu_v6_proc_fin
.word cpu_v6_reset
.word cpu_v6_do_idle
.word cpu_v6_dcache_clean_area
.word cpu_v6_switch_mm
.word cpu_v6_set_pte_ext
.size v6_processor_functions, . – v6_processor_functions
.type cpu_arch_name, #object
cpu_arch_name:
.asciz “armv6”
.size cpu_arch_name, . – cpu_arch_name
.type cpu_elf_name, #object
cpu_elf_name:
.asciz “v6”
.size cpu_elf_name, . – cpu_elf_name
.align
.section “.proc.info.init”, #alloc, #execinstr /*参考vmlinux.lds.S，可以看到这个段对应__proc_info_begin，从head-common.S知道，__proc_info_begin是由__lookup_processor_type这个函数调用，从而得到具体某个处理器的信息。*/
/*
* Match any ARMv6 processor core.
*/
.type __v6_proc_info, #object /*这个段就定义了这个结构体，对应procinfo.h里面的proc_info_list结构*/
__v6_proc_info:
.long 0x0007b000 /*cpu_val*/
.long 0x0007f000 /*cpu_mask*/
.long PMD_TYPE_SECT | \ /*__cpu_mm_mmu_flags*/
PMD_SECT_BUFFERABLE | \
PMD_SECT_CACHEABLE | \
PMD_SECT_AP_WRITE | \
PMD_SECT_AP_READ
.long PMD_TYPE_SECT | \ /*__cpu_io_mmu_flags*/
PMD_SECT_XN | \
PMD_SECT_AP_WRITE | \
PMD_SECT_AP_READ
b __v6_setup /*__cpu_flush，看上面的__v6_setup*/
.long cpu_arch_name /*arch_name*/
.long cpu_elf_name /*elf_name*/
.long HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_JAVA /*elf_hwcap*/
.long cpu_v6_name /*cpu_name*/
.long v6_processor_functions /*proc*/
.long v6wbi_tlb_fns /*tlb*/
.long v6_user_fns /*user*/
.long v6_cache_fns /*cache*/
.size __v6_proc_info, . – __v6_proc_info /*大小*/