linux的/arch/arm/boot/compressed/vmlinux.lds，内核一切从这里开始

这里以linux 2.6.28.6内核为例。

编译内核时选择压缩内核而且是arm架构，则Makefile调用的lds文件由arch/arm/boot/compressed/vmlinux.lds.in生成vmlinux.lds文件供连接器使用。因为连接时增加了-fpic参数，所以所有代码都是地址无关的，需要实际运行时用GOT和PLT的方法重定位。

(需要注意区别：

1. arch/arm/kernel/有vmlinux.lds.S和head.S：真正的内核lds和入口，会调用start_kernel函数进入init/main.c，然后进入内核。

2. arch/arm/boot/compressed/vmlinux.lds.in和head.S：uboot之后的入口，它会解压缩内核piggy.gz(用gzip压缩出来的含有上面的head.S和main.c等内核代码的文件)，然后进入真正的内核head.S入口。

3. mkimage会把64字节的头加上zimage（含有boot/compressed/head.S，misc.c，piggy.S，big-endian.S和piggy.gz构成）做成uboot可用的映象。)

OUTPUT_ARCH(arm)
ENTRY(_start)                       /*从_start开始执行*/
SECTIONS
{
. = TEXT_START;
_text = .;

.text : {
_start = .;                        /*从_start就是从start段开始执行*/
*(.start)
*(.text)
*(.text.*)
*(.fixup)
*(.gnu.warning)
*(.rodata)
*(.rodata.*)
*(.glue_7)
*(.glue_7t)
*(.piggydata)
. = ALIGN(4);
}

_etext = .;

_got_start = .;
.got               : { *(.got) }
_got_end = .;
.got.plt          : { *(.got.plt) }
.data               : { *(.data) }
_edata = .;

. = BSS_START;
__bss_start = .;
.bss               : { *(.bss) }
_end = .;

.stack (NOLOAD)     : { *(.stack) }

.stab 0          : { *(.stab) }
.stabstr 0          : { *(.stabstr) }
.stab.excl 0          : { *(.stab.excl) }
.stab.exclstr 0     : { *(.stab.exclstr) }
.stab.index 0          : { *(.stab.index) }
.stab.indexstr 0     : { *(.stab.indexstr) }
.comment 0          : { *(.comment) }
}